D 语言以系统编程语言而闻名，但它也是编写脚本的一个很好的选择。

D 语言由于其静态类型和元编程能力，经常被宣传为系统编程语言。然而，它也是一种非常高效的脚本语言。

由于 Python 在自动化任务和快速实现原型想法方面的灵活性，它通常被选为脚本语言。这使得 Python 对系统管理员、管理者和一般的开发人员非常有吸引力，因为它可以自动完成他们可能需要手动完成的重复性任务。

我们自然也可以期待任何其他的脚本编写语言具有 Python 的这些特性和能力。以下是我认为 D 是一个不错的选择的两个原因。

1、D 很容易读和写

作为一种类似于 C 的语言，D 应该是大多数程序员所熟悉的。任何使用 JavaScript、Java、PHP 或 Python 的人对 D 语言都很容易上手。

如果你还没有安装 D，请安装 D 编译器，这样你就可以运行本文中的 D 代码。你也可以使用在线 D 编辑器。

下面是一个 D 代码的例子，它从一个名为 words.txt 的文件中读取单词，并在命令行中打印出来：

open
source
is
cool

用 D 语言写脚本:

#!/usr/bin/env rdmd
// file print_words.d

// import the D standard library
import std;

void main(){
    // open the file
     File("./words.txt")

         //iterate by line
        .byLine

        // print each number
        .each!writeln;
}

这段代码以 释伴) 开头，它将使用 rdmd 来运行这段代码，rdmd 是 D 编译器自带的编译和运行代码的工具。假设你运行的是 Unix 或 Linux，在运行这个脚本之前，你必须使用chmod 命令使其可执行：

chmod u+x print_words.d

现在脚本是可执行的，你可以运行它：

./print_words.d

这将在你的命令行中打印以下内容：

open
source
is
cool

恭喜你，你写了第一个 D 语言脚本。你可以看到 D 是如何让你按顺序链式调用函数，这让阅读代码的感觉很自然，类似于你在头脑中思考问题的方式。这个功能让 D 成为我最喜欢的编程语言。

试着再写一个脚本：一个非营利组织的管理员有一个捐款的文本文件，每笔金额都是单独的一行。管理员想把前 10 笔捐款相加，然后打印出金额：

#!/usr/bin/env rdmd
// file sum_donations.d

import std;

void main()
{
    double total = 0;

    // open the file
    File("monies.txt")

         // iterate by line
        .byLine

         // pick first 10 lines
        .take(10)

        // remove new line characters (\n)
        .map!(strip)

         // convert each to double
        .map!(to!double)

        // add element to total
        .tee!((x) { total += x; })

        // print each number
        .each!writeln;

    // print total
    writeln("total: ", total);
}

与 each 一起使用的 ! 操作符是模板参数的语法。

2、D 是快速原型设计的好帮手

D 是灵活的，它可以快速地将代码敲打在一起，并使其发挥作用。它的标准库中包含了丰富的实用函数，用于执行常见的任务，如操作数据（JSON、CSV、文本等）。它还带有一套丰富的通用算法，用于迭代、搜索、比较和 mutate 数据。这些巧妙的算法通过定义通用的 基于范围的接口 而按照序列进行处理。

上面的脚本显示了 D 中的链式调用函数如何提供顺序处理和操作数据的要领。D 的另一个吸引人的地方是它不断增长的用于执行普通任务的第三方包的生态系统。一个例子是，使用 Vibe.d web 框架构建一个简单的 web 服务器很容易。下面是一个例子：

#!/usr/bin/env dub
/+ dub.sdl:
dependency "vibe-d" version="~>0.8.0"
+/
void main()
{
    import vibe.d;
    listenHTTP(":8080", (req, res) {
        res.writeBody("Hello, World: " ~ req.path);
    });
    runApplication();
}

它使用官方的 D 软件包管理器 Dub，从 D 软件包仓库中获取 vibe.d Web 框架。Dub 负责下载 Vibe.d 包，然后在本地主机 8080 端口上编译并启动一个 web 服务器。

尝试一下 D 语言

这些只是你可能想用 D 来写脚本的几个原因。

D 是一种非常适合开发的语言。你可以很容易从 D 下载页面安装，因此下载编译器，看看例子，并亲自体验 D 语言。

via: https://opensource.com/article/21/1/d-scripting

作者：Lawrence Aberba 选题：lujun9972 译者：geekpi 校对：wxy

本文由 LCTT 原创编译，Linux中国 荣誉推出

UFCS 能让你能够编写自然的可重用代码而不会牺牲便利性。

早在 2017 年，我就写过为什么 D 语言是开发的绝佳选择的文章。但是 D 语言中有一个出色的功能我没有充分的展开介绍： 通用函数调用语法 Universal Function Call Syntax （UFCS）。UFCS 是 D 语言中的一种语法糖，它可以在类型（字符串、数字、布尔值等）上链接任何常规函数，就像该类型的成员函数一样。

如果你尚未安装 D 语言，请安装 D 语言编译器，以便你可以自己运行 D 代码。

看一下以下示例代码：

// file: ufcs_demo.d

module ufcs_demo;

import std.stdio : writeln;

int[] evenNumbers(int[] numbers)
{
    import std.array : array;
    import std.algorithm : filter;

    return numbers.filter!(n => n % 2 == 0).array;
}

void main()
{
    writeln(evenNumbers([1, 2, 3, 4]));
}

使用你喜欢的 D 语言编译器进行编译，查看这个简单示例应用做了什么：

$ dmd ufcs_demo.d
$ ./ufcs_demo
[2, 4]

但是，使用作为 D 语言的内置功能的 UFCS ，你还可以自然方式编写代码：

...
writeln([1, 2, 3, 4].evenNumbers());
...

或完全删除现在多余的括号，使 evenNumbers 看起来像是一个属性：

...
writeln([1, 2, 3, 4].evenNumbers); // prints 2, 4
...

因此，完整的代码现在变为：

// file: ufcs_demo.d

module ufcs_demo;

import std.stdio : writeln;

int[] evenNumbers(int[] numbers)
{
    import std.array : array;
    import std.algorithm : filter;

    return numbers.filter!(n => n % 2 == 0).array;
}

void main()
{
    writeln([1, 2, 3, 4].evenNumbers);
}

使用你最喜欢的 D 语言编译器进行编译，然后尝试一下。 如预期的那样，它产生相同的输出：

$ dmd ufcs_demo.d
$ ./ufcs_demo
[2, 4]

在编译过程中，编译器自动地将数组作为函数的第一个参数。这是一个常规模式，使得使用 D 语言成为一种乐趣，因此，它与你自然而然考虑代码的感觉非常相似。结果就是函数式编程。

你可能会猜出这打印的是什么：

//file: cool.d
import std.stdio : writeln;
import std.uni : asLowerCase, asCapitalized;

void main()
{
    string mySentence = "D IS COOL";
    writeln(mySentence.asLowerCase.asCapitalized);
}

确认一下：

$ dmd cool.d
$ ./cool
D is cool

结合其他 D 语言的功能，UFCS 使你能够编写可重用的代码，并在不牺牲便利性的情况下自然地进行编写。

是时候尝试 D 语言了

就像我之前写的那样，D 语言是一种很棒的开发语言。从 D 语言的下载页面可以很容易地进行安装，因此请下载编译器，查看示例，并亲自体验 D 语言。

via: https://opensource.com/article/20/7/d-programming

作者：Lawrence Aberba 选题：lujun9972 译者：geekpi 校对：wxy

本文由 LCTT 原创编译，Linux中国 荣誉推出

D 语言的模块化、开发效率、可读性以及其它一些特性使其非常适合用于协同软件的开发。

D 编程语言是一种静态类型的通用编程语言，它具有和 C 语言类似的语法，能够编译为本地代码。许多理由使得它很适合用于开源软件开发，下面讲到的是其中一些理由。

模块化能力

在大多数情况下，当你有一个好的想法，你可以完全按照你的内心所想的方式通过代码来实现它。然而，有的时候，你不得让你的想法向代码妥协，而不是通过模块化代码来适应想法。D 语言支持多种编程范式，包括函数式风格、命令式、面向对象、元编程、并发（演员模式），这些全都和谐共存。你可以选择任何一种方便的编程范式来将你的想法转换为代码。

通过使用模板，可以生成额外的 D 代码并在编译的过程中把它编排进去，你可以把这些代码描述成编译器生成代码的一种模式。这是一种非常有用的设计算法，无需把它们绑定到任何特定的类型。由于模版的通用性，就很容易生成平台无关的代码。通过将模板与条件编译结合，跨平台的应用变得更加容易实现，也更容易接受来自使用不同操作系统的开发者的贡献。有了这一点，一个程序员可以通过很少的代码，利用有限的时间实现很多东西。

range 已经深度集成到了 D 语言中，相对于具体实现，它抽象出容器元素（比如数组、关联数组和链表等）是如何访问的。这个抽象使得可以在许多容器类型中设计和使用大量的算法，而无需绑定到特定的数据结构。D 的数组切片是 range 的一个实现。最终，你可以用很少的时间写很少的代码，并且只需要很低的维护成本。

开发效率

大多数开源软件的代码贡献者都是基于有限的时间志愿工作的。 D 语言能够极大的提高开发效率，因为你可以用更少的时间完成更多的事情。D 的模板和 range 使得程序员在开发通用代码和可复用代码时效率更高，但这些仅仅是 D 开发效率高的其中几个优势。另外一个主要的吸引力是， D 的编译速度看起来感觉就像解释型语言一样，比如 Python、JavaScript、Ruby 和 PHP，它使得 D 能够快速成型。

D 可以很容易的与旧的代码进行对接，减少了移植的需要。它的设计目的是与 C 代码进行自然地对接，毕竟， C 语言大量用在遗留代码、精心编写而测试过的代码、库以及低级系统调用（特别是 Linux 系统）上。C++ 代码在 D 中也是可调用的，从而进行更大的扩展。事实上，Python、Objective-C、Lua 和 Fortran 这些语言在技术层面上都是可以在 D 中使用的，有许多第三方正在努力在把 D 语言推向这些领域。这使得大量的开源库在 D 中均可使用，这符合开源软件开发的惯例。

可读性和可维护性

import std.stdio; // 导入标准输入/输出模块
void main()
{
    writeln("Hello, World!");
}

D 语言的 Hello, World 演示

对于熟悉 C 语言的人来说， D 代码很容易理解。另外， D 代码的可读性很强，即使是复杂的代码。这使得很容易发现错误。可读性对于吸引贡献者来说也是很重要的，这是开源软件成长的关键。

在 D 中一个非常简单但很有用的语法糖是支持使用下滑线分隔数字，这使得数字的可读性更高。这在数学上很有用：

int count = 100_000_000;
double price = 20_220.00 + 10.00;
int number = 0x7FFF_FFFF; // 16 进制系统

ddoc 是一个内建的工具，它能够很容易的自动根据代码注释生成文档，而不需要使用额外的工具。文档写作、改进和更新变得更加简单，不具挑战性，因为它伴随代码同时生成。

Contract 能够检查代码的实现，从而确保 D 代码的行为能够像期望的那样。就像法律契约的签订是为了确保每一方在协议中做自己该做的事情，在 D 语言中的契约式编程，能够确保实现的每一个函数、类等如期望的那样产生预期的结果和行为。这样一个特性对于错误检查非常实用，特别是在开源软件中，当多个人合作一个项目的时候。契约是大项目的救星。D 语言强大的契约式编程特性是内建的，而不是后期添加的。契约不仅使得使用 D 语言更加方便，也减少了正确写作和维护困难的头痛。

方便

协同开发是具有挑战性的，因为代码经常发生变化，并且有许多移动部分。D 语言通过支持在本地范围内导入模块，从而缓解了那些问题：

// 返回偶数
int[] evenNumbers(int[] numbers)
{
    // "filter" and "array" are only accessible locally
    import std.algorithm: filter; 
    import std.array: array;
    return numbers.filter!(n => n%2 == 0).array;
}

对 filter 使用 ! 运算符是模板参数的一个语法

上面的函数可以在不破坏代码的情况下调用，因为它不依赖任何全局导入模块。像这样实现的函数都可以在后期无需破坏代码的情况下增强，这是协同开发的好东西。

通用函数调用语法（UFCS）是 D 语言中的一个语法糖，它允许像调用一个对象的成员函数那样调用常规函数。一个函数的定义如下：

void cook(string food, int quantity)
{
    import std.stdio: writeln;
    writeln(food, " in quantity of ", quantity);
}

它能够以通常的方式调用：

string food = "rice";
int quantity = 3;

cook(food, quantity);

通过 UFCS，这个函数也可以像下面这样调用，看起来好像 cook 是一个成员函数：

string food = "rice";
int quantity = 3;

food.cook(quantity);

在编译过程中，编译器会自动把 food 作为 cook 函数的第一个参数。UFCS 使得它能够链起来常规函数，给你的代码产生一种函数风格编程的自然感觉。UFCS 在 D 语言中被大量使用，就像在上面的 evenNumbers 函数中使用的 filter 和 array 函数那样。结合模板、range、条件编译和 UFCS 能够在不牺牲方便性的前提下给予你强大的力量。

auto 关键词可以用来代替任何类型。编译器在编译过程中会静态推断类型。这样可以省去输入很长的类型名字，让你感觉写 D 代码就像是在写动态类型语言。

// Nope. Do you?
VeryLongTypeHere variable = new VeryLongTypeHere(); 

// 使用 auto 关键词
auto variable =  new VeryLongTypeHere();
auto name = "John Doe";
auto age = 12;
auto letter  = 'e';
auto anArray = [1, 2.0, 3, 0, 1.5]; // type of double[]
auto dictionary = ["one": 1, "two": 2, "three": 3]; // type of int[string]
auto cook(string food) {...} // auto for a function return type

D 的foreach 循环允许遍历各种不同的底层数据类型的集合和 range：

foreach(name; ["John", "Yaw", "Paul", "Kofi", "Ama"])
{
    writeln(name);
}

foreach(number; [1, 2, 3, 4, 4, 6]) {...}

foreach(number; 0..10) {...} // 0..10 is the syntax for number range

class Student {...}
Student[] students = [new Student(), new Student()];
foreach(student; students) {...}

D 语言中内建的单元测试不仅免除了使用外部工具的需要，也方便了程序员在自己的代码中执行测试。所有的测试用例都位于可定制的 unittest{} 块中：

int[] evenNumbers(int[] numbers)
{
    import std.algorithm: filter; 
    import std.array: array;
    return numbers.filter!(n => n%2 == 0).array;
}

unittest
{
    assert( evenNumbers([1, 2, 3, 4]) == [2, 4] );
}

使用 D 语言的标准编译器 DMD，你可以通过增加 -unittest 编译器标志把所有的测试编译进可执行结果中。

Dub 是 D 语言的一个内建包管理器和构建工具，使用它可以很容易的添加来自 Dub package registry 的第三方库。Dub 可以在编译过程中下载、编译和链接这些包，同时也会升级到新版本。

选择

除了提供多种编程范例和功能特性外，D 还提供其他的选择。它目前有三个可用的开源编译器。官方编译器 DMD 使用它自己的后端，另外两个编译器 GDC 和 LDC，分别使用 GCC 和 LLVM 后端。DMD 以编译速度块而著称，而 LDC 和 GDC 则以在很短的编译时间内生成快速生成机器代码而著称。你可以自由选择其中一个以适应你的使用情况。

默认情况下，D 语言是采用垃圾收集的内存分配方式的。你也可以选择手动进行内存管理，如果你想的话，甚至可以进行引用计数。一切选择都是你的。

更多

在这个简要的讨论中，还有许多 D 语言好的特性没有涉及到。我强烈推荐阅读 D 语言的特性概述，这是隐藏在标准库中的宝藏，以及 D 语言的使用区域，从而进一步了解人们用它来干什么。许多组织已经使用 D 语言来进行开发。最后，如果你打算开始学习 D 语言，那么请看这本书 D 语言编程。

（题图：opensource.com）

via: https://opensource.com/article/17/5/d-open-source-software-development

作者：Lawrence Aberba 译者：ucasFL 校对：wxy

本文由 LCTT 原创编译，Linux中国 荣誉推出