OK05 课程构建于课程 OK04 的基础，使用它来闪烁摩尔斯电码的 SOS 序列（...---...）。这里假设你已经有了 课程 4：OK04 操作系统的代码作为基础。

1、数据

到目前为止，我们与操作系统有关的所有内容提供的都是指令。然而有时候，指令只是完成了一半的工作。我们的操作系统可能还需要数据。

一些早期的操作系统确实只允许特定文件中的特定类型的数据，但是这通常被认为限制太多了。现代方法确实可以使程序变得复杂的多。

通常，数据就是些很重要的值。你可能接受过培训，认为数据就是某种类型的，比如，文本文件包含文本，图像文件包含图片，等等。说实话，这只是你的想法而已。计算机上的全部数据都是二进制数字，重要的是我们选择用什么来解释这些数据。在这个例子中，我们会用一个闪灯序列作为数据保存下来。

在 main.s 结束处复制下面的代码：

.section .data %定义 .data 段
.align 2 %对齐
pattern: %定义整形变量
.int 0b11111111101010100010001000101010

.align num 确保下一行代码的地址是 2 ^num 的整数倍。

.int val 输出数值 val。

要区分数据和代码，我们将数据都放在 .data 区域。我已经将该区域包含在操作系统的内存布局图。我选择将数据放到代码后面。将我们的指令和数据分开保存的原因是，如果最后我们在自己的操作系统上实现一些安全措施，我们就需要知道代码的那些部分是可以执行的，而那些部分是不行的。

我在这里使用了两个新命令 .align 和 .int。.align 保证接下来的数据是按照 2 的乘方对齐的。在这个里，我使用 .align 2 ，意味着数据最终存放的地址是 2 ²⁼⁴ 的整数倍。这个操作是很重要的，因为我们用来读取内存的指令 ldr 要求内存地址是 4 的倍数。

命令 .int 直接复制它后面的常量到输出。这意味着 11111111101010100010001000101010 ₂ 将会被存放到输出，所以该标签模式实际是将这段数据标识为模式。

关于数据的一个挑战是寻找一个高效和有用的展示形式。这种保存一个开、关的时间单元的序列的方式，运行起来很容易，但是将很难编辑，因为摩尔斯电码的 - 或 . 样式丢失了。

如我提到的，数据可以代表你想要的所有东西。在这里我编码了摩尔斯电码的 SOS 序列，对于不熟悉的人，就是 ...---...。我使用 0 表示一个时间单元的 LED 灭灯，而 1 表示一个时间单元的 LED 亮。这样，我们可以像这样编写一些代码在数据中显示一个序列，然后要显示不同序列，我们所有需要做的就是修改这段数据。下面是一个非常简单的例子，操作系统必须一直执行这段程序，解释和展示数据。

复制下面几行到 main.s 中的标记 loop$ 之前。

ptrn .req r4 %重命名 r4 为 ptrn
ldr ptrn,=pattern %加载 pattern 的地址到 ptrn
ldr ptrn,[ptrn] %加载地址 ptrn 所在内存的值
seq .req r5 %重命名 r5 为 seq
mov seq,#0 %seq 赋值为 0

这段代码加载 pattrern 到寄存器 r4，并加载 0 到寄存器 r5。r5 将是我们的序列位置，所以我们可以追踪我们已经展示了多少个 pattern。

如果 pattern 的当前位置是 1 且仅有一个 1，下面的代码将非零值放入 r1。

mov r1,#1 %加载1到 r1
lsl r1,seq %对r1 的值逻辑左移 seq 次
and r1,ptrn %按位与

这段代码对你调用 SetGpio 很有用，它必须有一个非零值来关掉 LED，而一个 0 值会打开 LED。

现在修改 main.s 中你的全部代码，这样代码中每次循环会根据当前的序列数设置 LED，等待 250000 毫秒（或者其他合适的延时），然后增加序列数。当这个序列数到达 32 就需要返回 0。看看你是否能实现这个功能，作为额外的挑战，也可以试着只使用一条指令。

2、当你玩得开心时，时间过得很快

你现在准备好在树莓派上实验。应该闪烁一串包含 3 个短脉冲，3 个长脉冲，然后 3 个短脉冲的序列。在一次延时之后，这种模式应该重复。如果这不工作，请查看我们的问题页。

一旦它工作，祝贺你已经抵达 OK 系列教程的结束点。

在这个系列我们学习了汇编代码，GPIO 控制器和系统定时器。我们已经学习了函数和 ABI，以及几个基础的操作系统原理，已经关于数据的知识。

你现在已经可以准备学习下面几个更高级的课程的某一个。

• Screen 系列是接下来的，会教你如何通过汇编代码使用屏幕。
• Input 系列教授你如何使用键盘和鼠标。

到现在，你已经有了足够的信息来制作操作系统，用其它方法和 GPIO 交互。如果你有任何机器人工具，你可能会想尝试编写一个通过 GPIO 管脚控制的机器人操作系统。

via: https://www.cl.cam.ac.uk/projects/raspberrypi/tutorials/os/ok05.html

作者：Robert Mullins 选题：lujun9972 译者：ezio 校对：wxy

本文由 LCTT 原创编译，Linux中国 荣誉推出

OK04 课程在 OK03 的基础上进行构建，它教你如何使用定时器让 OK 或 ACT LED 灯按精确的时间间隔来闪烁。假设你已经有了 课程 3：OK03 的操作系统，我们将以它为基础来构建。

1、一个新设备

定时器是树莓派保持时间的唯一方法。大多数计算机都有一个电池供电的时钟，这样当计算机关机后仍然能保持时间。

到目前为止，我们仅看了树莓派硬件的一小部分，即 GPIO 控制器。我只是简单地告诉你做什么，然后它会发生什么事情。现在，我们继续看定时器，并继续带你去了解它的工作原理。

和 GPIO 控制器一样，定时器也有地址。在本案例中，定时器的基地址在 20003000 ₁₆。阅读手册我们可以找到下面的表：

表 1.1 GPIO 控制器寄存器

这个表只告诉我们一部分内容，在手册中描述了更多的字段。手册上解释说，定时器本质上是按每微秒将计数器递增 1 的方式来运行。每次它是这样做的，它将计数器的低 32 位（4 字节）与 4 个比较器寄存器进行比较，如果匹配它们中的任何一个，它更新 Control/Status 以反映出其中有一个是匹配的。

关于 位 bit 、 字节 byte 、 位字段 bit field 、以及数据大小的更多内容如下：

一个位是一个单个的二进制数的名称。你可能还记得，一个单个的二进制数既可能是一个 1，也可能是一个 0。

一个字节是一个 8 位集合的名称。由于每个位可能是 1 或 0 这两个值的其中之一，因此，一个字节有 2 ⁸ = 256 个不同的可能值。我们一般解释一个字节为一个介于 0 到 255（含）之间的二进制数。

一个位字段是解释二进制的另一种方式。二进制可以解释为许多不同的东西，而不仅仅是一个数字。一个位字段可以将二进制看做为一系列的 1（开） 或 0（关）的开关。对于每个小开关，我们都有一个意义，我们可以使用它们去控制一些东西。我们已经遇到了 GPIO 控制器使用的位字段，使用它设置一个针脚的开或关。位为 1 时 GPIO 针脚将准确地打开或关闭。有时我们需要更多的选项，而不仅仅是开或关，因此我们将几个开关组合到一起，比如 GPIO 控制器的函数设置（如上图），每 3 位为一组控制一个 GPIO 针脚的函数。

我们的目标是实现一个函数，这个函数能够以一个时间数量为输入来调用它，这个输入的时间数量将作为等待的时间，然后返回。想一想如何去做，想想我们都拥有什么。

我认为这将有两个选择：

1. 从计数器中读取一个值，然后保持分支返回到相同的代码，直到计数器的等待时间数量大于它。
2. 从计数器中读取一个值，加上要等待的时间数量，将它保存到比较器寄存器，然后保持分支返回到相同的代码处，直到 Control / Status 寄存器更新。

这两种策略都工作的很好，但在本教程中，我们将只实现第一个。原因是比较器寄存器更容易出错，因为在增加等待时间并保存它到比较器的寄存器期间，计数器可能已经增加了，并因此可能会不匹配。如果请求的是 1 微秒（或更糟糕的情况是 0 微秒）的等待，这样可能导致非常长的意外延迟。

像这样存在被称为“并发问题”的问题，并且几乎无法解决。

2、实现

我将把这个创建完美的等待方法的挑战基本留给你。我建议你将所有与定时器相关的代码都放在一个名为 systemTimer.s 的文件中（理由很明显）。关于这个方法的复杂部分是，计数器是一个 8 字节值，而每个寄存器仅能保存 4 字节。所以，计数器值将分到 2 个寄存器中。

大型的操作系统通常使用等待函数来抓住机会在后台执行任务。

下列的代码块是一个示例。

ldrd r0,r1,[r2,#4]

ldrd regLow,regHigh,[src,#val] 从 src 中的数加上 val 之和的地址加载 8 字节到寄存器 regLow 和 regHigh 中。

上面的代码中你可以发现一个很有用的指令是 ldrd。它加载 8 字节的内存到两个寄存器中。在本案例中，这 8 字节内存从寄存器 r2 中的地址 + 4 开始，将被复制进寄存器 r0 和 r1。这种安排的稍微复杂之处在于 r1 实际上只持有了高位 4 字节。换句话说就是，如果如果计数器的值是 999,999,999,999 ₁₀ = 1110100011010100101001010000111111111111 ₂ ，那么寄存器 r1 中只有 11101000 ₂，而寄存器 r0 中则是 11010100101001010000111111111111 ₂。

实现它的更明智的方式应该是，去计算当前计数器值与来自方法启动后的那一个值的差，然后将它与要求的等待时间数量进行比较。除非恰好你希望的等待时间是占用 8 字节的，否则上面示例中寄存器 r1 中的值将会丢弃，而计数器仅需要使用低位 4 字节。

当等待开始时，你应该总是确保使用大于比较，而不是使用等于比较，因为如果你尝试去等待一个时间，而这个时间正好等于方法开始的时间与结束的时间之差，那么你就错过这个值而永远等待下去。

如果你不明白如何编写等待函数的代码，可以参考下面的指南。

借鉴 GPIO 控制器的创意，第一个函数我们应该去写如何取得系统定时器的地址。示例如下：

.globl GetSystemTimerBase
GetSystemTimerBase:
ldr r0,=0x20003000
mov pc,lr

另一个被证明非常有用的函数是返回在寄存器 r0 和 r1 中的当前计数器值：

.globl GetTimeStamp
GetTimeStamp:
push {lr}
bl GetSystemTimerBase
ldrd r0,r1,[r0,#4]
pop {pc}

这个函数简单地使用了 GetSystemTimerBase 函数，并像我们前面学过的那样，使用 ldrd 去加载当前计数器值。

现在，我们可以去写我们的等待方法的代码了。首先，在该方法启动后，我们需要知道计数器值，我们可以使用 GetTimeStamp 来取得。

delay .req r2
mov delay,r0
push {lr}
bl GetTimeStamp
start .req r3
mov start,r0

这个代码复制了我们的方法的输入，将延迟时间的数量放到寄存器 r2 中，然后调用 GetTimeStamp，这个函数将会返回寄存器 r0 和 r1 中的当前计数器值。接着复制计数器值的低位 4 字节到寄存器 r3 中。

接下来，我们需要计算当前计数器值与读入的值的差，然后持续这样做，直到它们的差至少是 delay 的大小为止。

loop$:

bl GetTimeStamp
elapsed .req r1
sub elapsed,r0,start
cmp elapsed,delay
.unreq elapsed
bls loop$

这个代码将一直等待，一直到等待到传递给它的时间数量为止。它从计数器中读取数值，减去最初从计数器中读取的值，然后与要求的延迟时间进行比较。如果过去的时间数量小于要求的延迟，它切换回 loop$。

.unreq delay
.unreq start
pop {pc}

代码完成后，函数返回。

3、另一个闪灯程序

你一旦明白了等待函数的工作原理，修改 main.s 去使用它。修改各处 r0 的等待设置值为某个很大的数量（记住它的单位是微秒），然后在树莓派上测试。如果函数不能正常工作，请查看我们的排错页面。

如果正常工作，恭喜你学会控制另一个设备了，会使用它，则时间由你控制。在下一节课程中，我们将完成 OK 系列课程的最后一节 课程 5：OK05，我们将使用我们已经学习过的知识让 LED 按我们的模式进行闪烁。

via: https://www.cl.cam.ac.uk/projects/raspberrypi/tutorials/os/ok04.html

作者：Robert Mullins 选题：lujun9972 译者：qhwdw 校对：wxy

本文由 LCTT 原创编译，Linux中国 荣誉推出

OK03 课程基于 OK02 课程来构建，它教你在汇编中如何使用函数让代码可复用和可读性更好。假设你已经有了 课程 2：OK02 的操作系统，我们将以它为基础。

1、可复用的代码

到目前为止，我们所写的代码都是以我们希望发生的事为顺序来输入的。对于非常小的程序来说，这种做法很好，但是如果我们以这种方式去写一个完整的系统，所写的代码可读性将非常差。我们应该去使用函数。

一个函数是一段可复用的代码片断，可以用于去计算某些答案，或执行某些动作。你也可以称它们为 过程 procedure 、 例程 routine 或 子例程 subroutine 。虽然它们都是不同的，但人们几乎都没有正确地使用这个术语。

你应该在数学上遇到了函数的概念。例如，余弦函数应用于一个给定的数时，会得到介于 -1 到 1 之间的另一个数，这个数就是角的余弦。一般我们写成 cos(x) 来表示应用到一个值 x 上的余弦函数。

在代码中，函数可以有多个输入（也可以没有输入），然后函数给出多个输出（也可以没有输出），并可能导致副作用。例如一个函数可以在一个文件系统上创建一个文件，第一个输入是它的名字，第二个输入是文件的长度。

函数可以认为是一个“黑匣子”。我们给它输入，然后它给我们输出，而我们不需要知道它是如何工作的。

在像 C 或 C++ 这样的高级代码中，函数是语言的组成部分。在汇编代码中，函数只是我们的创意。

理想情况下，我们希望能够在我们的寄存器中设置一些输入值，然后分支切换到某个地址，然后预期在某个时刻分支返回到我们代码，并通过代码来设置输出值到寄存器。这就是我们所设想的汇编代码中的函数。困难之处在于我们用什么样的方式去设置寄存器。如果我们只是使用平时所接触到的某种方法去设置寄存器，每个程序员可能使用不同的方法，这样你将会发现你很难理解其他程序员所写的代码。另外，编译器也不能像使用汇编代码那样轻松地工作，因为它们压根不知道如何去使用函数。为避免这种困惑，为每个汇编语言设计了一个称为 应用程序二进制接口 Application Binary Interface （ABI）的标准，由它来规范函数如何去运行。如果每个人都使用相同的方法去写函数，这样每个人都可以去使用其他人写的函数。在这里，我将教你们这个标准，而从现在开始，我所写的函数将全部遵循这个标准。

该标准规定，寄存器 r0、r1、r2 和 r3 将被依次用于函数的输入。如果函数没有输入，那么它不会在意值是什么。如果只需要一个输入，那么它应该总是在寄存器 r0 中，如果它需要两个输入，那么第一个输入在寄存器 r0 中，而第二个输入在寄存器 r1 中，依此类推。输出值也总是在寄存器 r0 中。如果函数没有输出，那么 r0 中是什么值就不重要了。

另外，该标准要求当一个函数运行之后，寄存器 r4 到 r12 的值必须与函数启动时的值相同。这意味着当你调用一个函数时，你可以确保寄存器 r4 到 r12 中的值没有发生变化，但是不能确保寄存器 r0 到 r3 中的值也没有发生变化。

当一个函数运行完成后，它将返回到启动它的代码分支处。这意味着它必须知道启动它的代码的地址。为此，需要一个称为 lr（链接寄存器）的专用寄存器，它总是在保存调用这个函数的指令后面指令的地址。

表 1.1 ARM ABI 寄存器用法

通常，函数需要使用很多的寄存器，而不仅是 r0 到 r3。但是，由于 r4 到 r12 必须在函数完成之后值必须保持相同，因此它们需要被保存到某个地方。我们将它们保存到称为栈的地方。

一个 栈 stack 就是我们在计算中用来保存值的一个很形象的方法。就像是摞起来的一堆盘子，你可以从上到下来移除它们，而添加它们时，你只能从下到上来添加。

在函数运行时，使用栈来保存寄存器值是个非常好的创意。例如，如果我有一个函数需要去使用寄存器 r4 和 r5，它将在一个栈上存放这些寄存器的值。最后用这种方式，它可以再次将它拿回来。更高明的是，如果为了运行完我的函数，需要去运行另一个函数，并且那个函数需要保存一些寄存器，在那个函数运行时，它将把寄存器保存在栈顶上，然后在结束后再将它们拿走。而这并不会影响我保存在寄存器 r4 和 r5 中的值，因为它们是在栈顶上添加的，拿走时也是从栈顶上取出的。

用来表示使用特定的方法将值放到栈上的专用术语，我们称之为那个方法的“ 栈帧 stack frame ”。不是每种方法都使用一个栈帧，有些是不需要存储值的。

因为栈非常有用，它被直接实现在 ARMv6 的指令集中。一个名为 sp（栈指针）的专用寄存器用来保存栈的地址。当需要有值添加到栈上时，sp 寄存器被更新，这样就总是保证它保存的是栈上第一个值的地址。push {r4,r5} 将推送 r4 和 r5 中的值到栈顶上，而 pop {r4,r5} 将（以正确的次序）取回它们。

2、我们的第一个函数

现在，关于函数的原理我们已经有了一些概念，我们尝试来写一个函数。由于是我们的第一个很基础的例子，我们写一个没有输入的函数，它将输出 GPIO 的地址。在上一节课程中，我们就是写到这个值上，但将它写成函数更好，因为我们在真实的操作系统中经常需要用到它，而我们不可能总是能够记住这个地址。

复制下列代码到一个名为 gpio.s 的新文件中。就像在 source 目录中使用的 main.s 一样。我们将把与 GPIO 控制器相关的所有函数放到一个文件中，这样更好查找。

.globl GetGpioAddress
GetGpioAddress:
ldr r0,=0x20200000
mov pc,lr

.globl lbl 使标签 lbl 从其它文件中可访问。

mov reg1,reg2 复制 reg2 中的值到 reg1 中。

这就是一个很简单的完整的函数。.globl GetGpioAddress 命令是通知汇编器，让标签 GetGpioAddress 在所有文件中全局可访问。这意味着在我们的 main.s 文件中，我们可以使用分支指令到标签 GetGpioAddress 上，即便这个标签在那个文件中没有定义也没有问题。

你应该认得 ldr r0,=0x20200000 命令，它将 GPIO 控制器地址保存到 r0 中。由于这是一个函数，我们必须要让它输出到寄存器 r0 中，我们不能再像以前那样随意使用任意一个寄存器了。

mov pc,lr 将寄存器 lr 中的值复制到 pc 中。正如前面所提到的，寄存器 lr 总是保存着方法完成后我们要返回的代码的地址。pc 是一个专用寄存器，它总是包含下一个要运行的指令的地址。一个普通的分支命令只需要改变这个寄存器的值即可。通过将 lr 中的值复制到 pc 中，我们就可以将要运行的下一行命令改变成我们将要返回的那一行。

理所当然这里有一个问题，那就是我们如何去运行这个代码？我们将需要一个特殊的分支类型 bl 指令。它像一个普通的分支一样切换到一个标签，但它在切换之前先更新 lr 的值去包含一个在该分支之后的行的地址。这意味着当函数执行完成后，将返回到 bl 指令之后的那一行上。这就确保了函数能够像任何其它命令那样运行，它简单地运行，做任何需要做的事情，然后推进到下一行。这是理解函数最有用的方法。当我们使用它时，就将它们按“黑匣子”处理即可，不需要了解它是如何运行的，我们只了解它需要什么输入，以及它给我们什么输出即可。

到现在为止，我们已经明白了函数如何使用，下一节我们将使用它。

3、一个大的函数

现在，我们继续去实现一个更大的函数。我们的第一项任务是启用 GPIO 第 16 号针脚的输出。如果它是一个函数那就太好了。我们能够简单地指定一个针脚号和一个函数作为输入，然后函数将设置那个针脚的值。那样，我们就可以使用这个代码去控制任意的 GPIO 针脚，而不只是 LED 了。

将下列的命令复制到 gpio.s 文件中的 GetGpioAddress 函数中。

.globl SetGpioFunction
SetGpioFunction:
cmp r0,#53
cmpls r1,#7
movhi pc,lr

带后缀 ls 的命令只有在上一个比较命令的结果是第一个数字小于或与第二个数字相同的情况下才会被运行。它是无符号的。

带后缀 hi 的命令只有上一个比较命令的结果是第一个数字大于第二个数字的情况下才会被运行。它是无符号的。

在写一个函数时，我们首先要考虑的事情就是输入，如果输入错了我们怎么办？在这个函数中，我们有一个输入是 GPIO 针脚号，而它必须是介于 0 到 53 之间的数字，因为只有 54 个针脚。每个针脚有 8 个函数，被编号为 0 到 7，因此函数编号也必须是 0 到 7 之间的数字。我们可以假设输入应该是正确的，但是当在硬件上使用时，这种做法是非常危险的，因为不正确的值将导致非常糟糕的副作用。所以，在这个案例中，我们希望确保输入值在正确的范围。

为了确保输入值在正确的范围，我们需要做一个检查，即 r0 <= 53 并且 r1 <= 7。首先我们使用前面看到的比较命令去将 r0 的值与 53 做比较。下一个指令 cmpls 仅在前一个比较指令结果是小于或与 53 相同时才会去运行。如果是这种情况，它将寄存器 r1 的值与 7 进行比较，其它的部分都和前面的是一样的。如果最后的比较结果是寄存器值大于那个数字，最后我们将返回到运行函数的代码处。

这正是我们所希望的效果。如果 r0 中的值大于 53，那么 cmpls 命令将不会去运行，但是 movhi 会运行。如果 r0 中的值 <= 53，那么 cmpls 命令会运行，它会将 r1 中的值与 7 进行比较，如果 r1 > 7，movhi 会运行，函数结束，否则 movhi 不会运行，这样我们就确定 r0 <= 53 并且 r1 <= 7。

ls（低于或相同）与 le（小于或等于）有一些细微的差别，以及后缀 hi（高于）和 gt（大于）也一样有一些细微差别，我们在后面将会讲到。

将这些命令复制到上面的代码的下面位置。

push {lr}
mov r2,r0
bl GetGpioAddress

push {reg1,reg2,...} 复制列出的寄存器 reg1、reg2、… 到栈顶。该命令仅能用于通用寄存器和 lr 寄存器。

bl lbl 设置 lr 为下一个指令的地址并切换到标签 lbl。

这三个命令用于调用我们第一个方法。push {lr} 命令复制 lr 中的值到栈顶，这样我们在后面可以获取到它。当我们调用 GetGpioAddress 时必须要这样做，我们将需要使用 lr 去保存我们函数要返回的地址。

如果我们对 GetGpioAddress 函数一无所知，我们必须假设它改变了 r0、r1、r2 和 r3 的值 ，并移动我们的值到 r4 和 r5 中，以在函数完成之后保持它们的值一样。幸运的是，我们知道 GetGpioAddress 做了什么，并且我们也知道它仅改变了 r0 为 GPIO 地址，它并没有影响 r1、r2 或 r3 的值。因此，我们仅去将 GPIO 针脚号从 r0 中移出，这样它就不会被覆盖掉，但我们知道，可以将它安全地移到 r2 中，因为 GetGpioAddress 并不去改变 r2。

最后我们使用 bl 指令去运行 GetGpioAddress。通常，运行一个函数，我们使用一个术语叫“调用”，从现在开始我们将一直使用这个术语。正如我们前面讨论过的，bl 调用一个函数是通过更新 lr 为下一个指令的地址并切换到该函数完成的。

当一个函数结束时，我们称为“返回”。当一个 GetGpioAddress 调用返回时，我们已经知道了 r0 中包含了 GPIO 的地址，r1 中包含了函数编号，而 r2 中包含了 GPIO 针脚号。

我前面说过，GPIO 函数每 10 个保存在一个块中，因此首先我们需要去判断我们的针脚在哪个块中。这似乎听起来像是要使用一个除法，但是除法做起来非常慢，因此对于这些比较小的数来说，不停地做减法要比除法更好。

将下面的代码复制到上面的代码中最下面的位置。

functionLoop$:

cmp r2,#9
subhi r2,#10
addhi r0,#4
bhi functionLoop$

add reg,#val 将数字 val 加到寄存器 reg 的内容上。

这个简单的循环代码将针脚号（r2）与 9 进行比较。如果它大于 9，它将从针脚号上减去 10，并且将 GPIO 控制器地址加上 4，然后再次运行检查。

这样做的效果就是，现在，r2 中将包含一个 0 到 9 之间的数字，它是针脚号除以 10 的余数。r0 将包含这个针脚的函数所设置的 GPIO 控制器的地址。它就如同是 “GPIO 控制器地址 + 4 × (GPIO 针脚号 ÷ 10)”。

最后，将下面的代码复制到上面的代码中最下面的位置。

add r2, r2,lsl #1
lsl r1,r2
str r1,[r0]
pop {pc}

移位参数 reg,lsl #val 表示将寄存器 reg 中二进制表示的数逻辑左移 val 位之后的结果作为与前面运算的操作数。

lsl reg,amt 将寄存器 reg 中的二进制数逻辑左移 amt 中的位数。

str reg,[dst] 与 str reg,[dst,#0] 相同。

pop {reg1,reg2,...} 从栈顶复制值到寄存器列表 reg1、reg2、… 仅有通用寄存器与 pc 可以这样弹出值。

这个代码完成了这个方法。第一行其实是乘以 3 的变体。乘法在汇编中是一个大而慢的指令，因为电路需要很长时间才能给出答案。有时使用一些能够很快给出答案的指令会让它变得更快。在本案例中，我们知道 r2 × 3 与 r2 × 2 + r2 是相同的。一个寄存器乘以 2 是非常容易的，因为它可以通过将二进制表示的数左移一位来很方便地实现。

ARMv6 汇编语言其中一个非常有用的特性就是，在使用它之前可以先移动参数所表示的位数。在本案例中，我将 r2 加上 r2 中二进制表示的数左移一位的结果。在汇编代码中，你可以经常使用这个技巧去更快更容易地计算出答案，但如果你觉得这个技巧使用起来不方便，你也可以写成类似 mov r3,r2； add r2,r3； add r2,r3 这样的代码。

现在，我们可以将一个函数的值左移 r2 中所表示的位数。大多数对数量的指令（比如 add 和 sub）都有一个可以使用寄存器而不是数字的变体。我们执行这个移位是因为我们想去设置表示针脚号的位，并且每个针脚有三个位。

然后，我们将函数计算后的值保存到 GPIO 控制器的地址上。我们在循环中已经算出了那个地址，因此我们不需要像 OK01 和 OK02 中那样在一个偏移量上保存它。

最后，我们从这个方法调用中返回。由于我们将 lr 推送到了栈上，因此我们 pop pc，它将复制 lr 中的值并将它推送到 pc 中。这个操作类似于 mov pc,lr，因此函数调用将返回到运行它的那一行上。

敏锐的人可能会注意到，这个函数其实并不能正确工作。虽然它将 GPIO 针脚函数设置为所要求的值，但它会导致在同一个块中的所有的 10 个针脚的函数都归 0！在一个大量使用 GPIO 针脚的系统中，这将是一个很恼人的问题。我将这个问题留给有兴趣去修复这个函数的人，以确保只设置相关的 3 个位而不去覆写其它位，其它的所有位都保持不变。关于这个问题的解决方案可以在本课程的下载页面上找到。你可能会发现非常有用的几个函数是 and，它是计算两个寄存器的布尔与函数，mvns 是计算布尔非函数，而 orr 是计算布尔或函数。

4、另一个函数

现在，我们已经有了能够管理 GPIO 针脚函数的函数。我们还需要写一个能够打开或关闭 GPIO 针脚的函数。我们不需要写一个打开的函数和一个关闭的函数，只需要一个函数就可以做这两件事情。

我们将写一个名为 SetGpio 的函数，它将 GPIO 针脚号作为第一个输入放入 r0 中，而将值作为第二个输入放入 r1 中。如果该值为 0，我们将关闭针脚，而如果为非零则打开针脚。

将下列的代码复制粘贴到 gpio.s 文件的结尾部分。

.globl SetGpio
SetGpio:
pinNum .req r0
pinVal .req r1

alias .req reg 设置寄存器 reg 的别名为 alias。

我们再次需要 .globl 命令，标记它为其它文件可访问的全局函数。这次我们将使用寄存器别名。寄存器别名允许我们为寄存器使用名字而不仅是 r0 或 r1。到目前为止，寄存器别名还不是很重要，但随着我们后面写的方法越来越大，它将被证明非常有用，现在开始我们将尝试使用别名。当在指令中使用到 pinNum .req r0 时，它的意思是 pinNum 表示 r0。

将下面的代码复制粘贴到上述的代码下面位置。

cmp pinNum,#53
movhi pc,lr
push {lr}
mov r2,pinNum
.unreq pinNum
pinNum .req r2
bl GetGpioAddress
gpioAddr .req r0

.unreq alias 删除别名 alias。

就像在函数 SetGpio 中所做的第一件事情是检查给定的针脚号是否有效一样。我们需要同样的方式去将 pinNum（r0）与 53 进行比较，如果它大于 53 将立即返回。一旦我们想要再次调用 GetGpioAddress，我们就需要将 lr 推送到栈上来保护它，将 pinNum 移动到 r2 中。然后我们使用 .unreq 语句来删除我们给 r0 定义的别名。因为针脚号现在保存在寄存器 r2 中，我们希望别名能够反映这个变化，因此我们从 r0 移走别名，重新定义到 r2。你应该每次在别名使用结束后，立即删除它，这样当它不再存在时，你就不会在后面的代码中因它而产生错误。

然后，我们调用了 GetGpioAddress，并且我们创建了一个指向 r0的别名以反映此变化。

将下面的代码复制粘贴到上述代码的后面位置。

pinBank .req r3
lsr pinBank,pinNum,#5a
lsl pinBank,#2
add gpioAddr,pinBank
.unreq pinBank

lsr dst,src,#val 将 src 中二进制表示的数右移 val 位，并将结果保存到 dst。

对于打开和关闭 GPIO 针脚，每个针脚在 GPIO 控制器上有两个 4 字节组。第一个 4 字节组每个位控制前 32 个针脚，而第二个 4 字节组控制剩下的 22 个针脚。为了判断我们要设置的针脚在哪个 4 字节组中，我们需要将针脚号除以 32。幸运的是，这很容易，因为它等价于将二进制表示的针脚号右移 5 位。因此，在本案例中，我们将 r3 命名为 pinBank，然后计算 pinNum ÷ 32。因为它是一个 4 字节组，我们需要将它与 4 相乘的结果。它与二进制表示的数左移 2 位相同，这就是下一行的命令。你可能想知道我们能否只将它右移 3 位呢，这样我们就不用先右移再左移。但是这样做是不行的，因为当我们做 ÷ 32 时答案有些位可能被舍弃，而如果我们做 ÷ 8 时却不会这样。

现在，gpioAddr 的结果有可能是 20200000 ₁₆（如果针脚号介于 0 到 31 之间），也有可能是 20200004 ₁₆（如果针脚号介于 32 到 53 之间）。这意味着如果加上 28 ₁₀，我们将得到打开针脚的地址，而如果加上 40 ₁₀ ，我们将得到关闭针脚的地址。由于我们用完了 pinBank ，所以在它之后立即使用 .unreq 去删除它。

将下面的代码复制粘贴到上述代码的下面位置。

and pinNum,#31
setBit .req r3
mov setBit,#1
lsl setBit,pinNum
.unreq pinNum

and reg,#val 计算寄存器 reg 中的数与 val 的布尔与。

该函数的下一个部分是产生一个正确的位集合的数。至于 GPIO 控制器去打开或关闭针脚，我们在针脚号除以 32 的余数里设置了位的数。例如，设置 16 号针脚，我们需要第 16 位设置数字为 1 。设置 45 号针脚，我们需要设置第 13 位数字为 1，因为 45 ÷ 32 = 1 余数 13。

这个 and 命令计算我们需要的余数。它是这样计算的，在两个输入中所有的二进制位都是 1 时，这个 and 运算的结果就是 1，否则就是 0。这是一个很基础的二进制操作，and 操作非常快。我们给定的输入是 “pinNum and 31 ₁₀ = 11111 ₂”。这意味着答案的后 5 位中只有 1，因此它肯定是在 0 到 31 之间。尤其是在 pinNum 的后 5 位的位置是 1 的地方它只有 1。这就如同被 32 整除的余数部分。就像 31 = 32 - 1 并不是巧合。

代码的其余部分使用这个值去左移 1 位。这就有了创建我们所需要的二进制数的效果。

将下面的代码复制粘贴到上述代码的下面位置。

teq pinVal,#0
.unreq pinVal
streq setBit,[gpioAddr,#40]
strne setBit,[gpioAddr,#28]
.unreq setBit
.unreq gpioAddr
pop {pc}

teq reg,#val 检查寄存器 reg 中的数字与 val 是否相等。

这个代码结束了该方法。如前面所说，当 pinVal 为 0 时，我们关闭它，否则就打开它。teq（等于测试）是另一个比较操作，它仅能够测试是否相等。它类似于 cmp ，但它并不能算出哪个数大。如果你只是希望测试数字是否相同，你可以使用 teq。

如果 pinVal 是 0，我们将 setBit 保存在 GPIO 地址偏移 40 的位置，我们已经知道，这样会关闭那个针脚。否则将它保存在 GPIO 地址偏移 28 的位置，它将打开那个针脚。最后，我们通过弹出 pc 返回，这将设置它为我们推送链接寄存器时保存的值。

5、一个新的开始

在完成上述工作后，我们终于有了我们的 GPIO 函数。现在，我们需要去修改 main.s 去使用它们。因为 main.s 现在已经有点大了，也更复杂了。将它分成两节将是一个很好的设计。到目前为止，我们一直使用的 .init 应该尽可能的让它保持小。我们可以更改代码来很容易地反映出这一点。

将下列的代码插入到 main.s 文件中 _start: 的后面：

b main

.section .text
main:
mov sp,#0x8000

在这里重要的改变是引入了 .text 节。我设计了 makefile 和链接器脚本，它将 .text 节（它是默认节）中的代码放在地址为 8000 ₁₆ 的 .init 节之后。这是默认加载地址，并且它给我们提供了一些空间去保存栈。由于栈存在于内存中，它也有一个地址。栈向下增长内存，因此每个新值都低于前一个地址，所以，这使得栈顶是最低的一个地址。

图中的 “ATAGs” 节的位置保存了有关树莓派的信息，比如它有多少内存，默认屏幕分辨率是多少。

用下面的代码替换掉所有设置 GPIO 函数针脚的代码：

pinNum .req r0
pinFunc .req r1
mov pinNum,#16
mov pinFunc,#1
bl SetGpioFunction
.unreq pinNum
.unreq pinFunc

这个代码将使用针脚号 16 和函数编号 1 去调用 SetGpioFunction。它的效果就是启用了 OK LED 灯的输出。

用下面的代码去替换打开 OK LED 灯的代码：

pinNum .req r0
pinVal .req r1
mov pinNum,#16
mov pinVal,#0
bl SetGpio
.unreq pinNum
.unreq pinVal

这个代码使用 SetGpio 去关闭 GPIO 第 16 号针脚，因此将打开 OK LED。如果我们（将第 4 行）替换成 mov pinVal,#1 它将关闭 LED 灯。用以上的代码去替换掉你关闭 LED 灯的旧代码。

6、继续向目标前进

但愿你能够顺利地在你的树莓派上测试我们所做的这一切。到目前为止，我们已经写了一大段代码，因此不可避免会出现错误。如果有错误，可以去查看我们的排错页面。

如果你的代码已经正常工作，恭喜你。虽然我们的操作系统除了做 课程 2：OK02 中的事情，还做不了别的任何事情，但我们已经学会了函数和格式有关的知识，并且我们现在可以更好更快地编写新特性了。现在，我们在操作系统上修改 GPIO 寄存器将变得非常简单，而它就是用于控制硬件的！

在 课程 4：OK04 中，我们将处理我们的 wait 函数，目前，它的时间控制还不精确，这样我们就可以更好地控制我们的 LED 灯了，进而最终控制所有的 GPIO 针脚。

via: https://www.cl.cam.ac.uk/projects/raspberrypi/tutorials/os/ok03.html

作者：Robert Mullins 选题：lujun9972 译者：qhwdw 校对：wxy

本文由 LCTT 原创编译，Linux中国 荣誉推出

OK02 课程构建于 OK01 课程的基础上，通过不停地打开和关闭 OK 或 ACT LED 指示灯来实现闪烁。假设你已经有了 课程 1：OK01 操作系统的代码，它将是这一节课的基础。

1、等待

等待是操作系统开发中非常有用的部分。操作系统经常发现自己无事可做，以及必须要延迟。在这个例子中，我们希望通过等待，让 LED 灯打开、关闭的闪烁可以看到。如果你只是打开和关闭它，你将看到这个视觉效果，因为计算机每秒种可以打开和关闭它好几千次（LCTT 译注：视觉暂留效应会使你难以发觉它的闪烁）。在后面的课程中，我们将看到精确的等待，但是现在，我们只要简单地去消耗时间就足够了。

mov r2,#0x3F0000
wait1$:
sub r2,#1
cmp r2,#0
bne wait1$

sub reg,#val 从寄存器 reg 中的值上减去数字 val

cmp reg,#val 将寄存器中的值与数字 val 进行比较。

如果最后的比较结果是不相等，那么执行后缀了 ne 的 b 命令。

上面是一个很常见的产生延迟的代码片段，由于每个树莓派基本上是相同的，所以产生的延迟大致也是相同的。它的工作原理是，使用一个 mov 命令将值 3F0000 ₁₆ 推入到寄存器 r2 中，然后将这个值减 1，直到这个值减到 0 为止。在这里使用了三个新命令 sub、 cmp 和 bne。

sub 是减法命令，它只是简单地从第一个参数中的值减去第二个参数中的值。

cmp 是个很有趣的命令。它将第一个参数与第二个参数进行比较，然后将比较结果记录到一个称为当前处理器状态寄存器的专用寄存器中。你其实不用担心它，它记住的只是两个数谁大或谁小，或是相等而已。 ¹

bne 其实是一个伪装的分支命令。在 ARM 汇编语言家族中，任何指令都可以有条件地运行。这意味着如果上一个比较结果是某个确定的结果，那个指令才会运行。这是个非常有意思的技巧，我们在后面将大量使用到它，但在本案例中，我们在 b 命令后面的 ne 后缀意思是 “只有在上一个比较的结果是值不相等，才去运行该分支”。ne 后缀可以使用在任何命令上，其它几个（总共 16 个）条件也是如此，比如 eq 表示等于，而 lt 表示小于。

2、组合到一起

上一节讲我提到过，通过将 GPIO 地址偏移量设置为 28（即：str r1,[r0,#28]）而不是 40 即可实现 LED 的关闭。因此，你需要去修改课程 OK01 的代码，在打开 LED 后，运行等待代码，然后再关闭 LED，再次运行等待代码，并包含一个回到开始位置的分支。注意，不需要重新启用 GPIO 的 16 号针脚的输出功能，这个操作只需要做一次就可以了。如果你想更高效，我建议你复用 r1 寄存器的值。所有课程都一样，你可以在 下载页面 找到所有的解决方案。需要注意的是，必须保证你的所有标签都是唯一的。当你写了 wait1$: 你其它行上的标签就不能再使用 wait1$ 了。

在我的树莓派上，它大约是每秒闪两次。通过改变我们所设置的 r2 寄存器中的值，可以很轻松地修改它。但是，不幸的是，我不能够精确地预测它的运行速度。如果你的树莓派未按预期正常工作，请查看我们的故障排除页面，如果它正常工作，恭喜你。

在这个课程中，我们学习了另外两个汇编命令：sub 和 cmp，同时学习了 ARM 中如何实现有条件运行。

在下一个课程，课程 3：OK03 中我们将学习如何编写代码，以及建立一些代码复用的标准，并且如果需要的话，可能会使用 C 或 C++ 来写代码。

1. 如果你点了这个链接，说明你一定想知道它的具体内容。CPSR 是一个由许多独立的比特位组成的 32 比特寄存器。它有一个位用于表示正数、零和负数。当一个 cmp 指令运行后，它从第一个参数上减去第二个参数，然后用这个位记下它的结果是正数、零还是负数。如果是零意味着它们相等（a-b=0 暗示着 a=b）如果为正数意味着 a 大于 b（a-b>0 暗示着 a>b），如果为负数意味着小于。还有其它比较指令，但 cmp 指令最直观。 ↩

via: https://www.cl.cam.ac.uk/projects/raspberrypi/tutorials/os/ok02.html

作者：Robert Mullins 选题：lujun9972 译者：qhwdw 校对：wxy

本文由 LCTT 原创编译，Linux中国 荣誉推出

OK01 课程讲解了树莓派如何入门，以及在树莓派上如何启用靠近 RCA 和 USB 端口的 OK 或 ACT 的 LED 指示灯。这个指示灯最初是为了指示 OK 状态的，但它在第二版的树莓派上被改名为 ACT。

1、入门

我们假设你已经访问了下载页面，并且已经获得了必需的 GNU 工具链。也下载了一个称为操作系统模板的文件。请下载这个文件并在一个新目录中解开它。

2、开始

现在，你已经展开了这个模板文件，在 source 目录中创建一个名为 main.s 的文件。这个文件包含了这个操作系统的代码。具体来看，这个文件夹的结构应该像下面这样：

build/
   (empty)
source/
   main.s
kernel.ld
LICENSE
Makefile

用文本编辑器打开 main.s 文件，这样我们就可以输入汇编代码了。树莓派使用了称为 ARMv6 的汇编代码变体，这就是我们即将要写的汇编代码类型。

扩展名为 .s 的文件一般是汇编代码，需要记住的是，在这里它是 ARMv6 的汇编代码。

首先，我们复制下面的这些命令。

.section .init
.globl _start
_start:

实际上，上面这些指令并没有在树莓派上做任何事情，它们是提供给汇编器的指令。汇编器是一个转换程序，它将我们能够理解的汇编代码转换成树莓派能够理解的机器代码。在汇编代码中，每个行都是一个新的命令。上面的第一行告诉汇编器 ¹ 在哪里放我们的代码。我们提供的模板中将它放到一个名为 .init 的节中的原因是，它是输出的起始点。这很重要，因为我们希望确保我们能够控制哪个代码首先运行。如果不这样做，首先运行的代码将是按字母顺序排在前面的代码！.section 命令简单地告诉汇编器，哪个节中放置代码，从这个点开始，直到下一个 .section 或文件结束为止。

在汇编代码中，你可以跳行、在命令前或后放置空格去提升可读性。

接下来两行是停止一个警告消息，它们并不重要。 ²

3、第一行代码

现在，我们正式开始写代码。计算机执行汇编代码时，是简单地一行一行按顺序执行每个指令，除非明确告诉它不这样做。每个指令都是开始于一个新行。

复制下列指令。

ldr r0,=0x20200000

ldr reg,=val 将数字 val 加载到名为 reg 的寄存器中。

那是我们的第一个命令。它告诉处理器将数字 0x20200000 保存到寄存器 r0 中。在这里我需要去回答两个问题， 寄存器 register 是什么？0x20200000 是一个什么样的数字？

寄存器在处理器中就是一个极小的内存块，它是处理器保存正在处理的数字的地方。处理器中有很多寄存器，很多都有专门的用途，我们在后面会一一接触到它们。最重要的有十三个（命名为 r0、r1、r2、…、r9、r10、r11、r12），它们被称为通用寄存器，你可以使用它们做任何计算。由于是写我们的第一行代码，我们在示例中使用了 r0，当然你可以使用它们中的任何一个。只要后面始终如一就没有问题。

树莓派上的一个单独的寄存器能够保存任何介于 0 到 4,294,967,295（含）之间的任意整数，它可能看起来像一个很大的内存，实际上它仅有 32 个二进制比特。

0x20200000 确实是一个数字。只不过它是以十六进制表示的。下面的内容详细解释了十六进制的相关信息：

延伸阅读：十六进制解释

十六进制是另一种表示数字的方式。你或许只知道十进制的数字表示方法，十进制共有十个数字：0、1、2、3、4、5、6、7、8 和 9。十六进制共有十六个数字：0、1、2、3、4、5、6、7、8、9、a、b、c、d、e 和 f。

你可能还记得十进制是如何用位制来表示的。即最右侧的数字是个位，紧接着的左边一位是十位，再接着的左边一位是百位，依此类推。也就是说，它的值是 100 × 百位的数字，再加上 10 × 十位的数字，再加上 1 × 个位的数字。

从数学的角度来看，我们可以发现规律，最右侧的数字是 10 ⁰ = 1s，紧接着的左边一位是 10 ¹ = 10s，再接着是 10 ² = 100s，依此类推。我们设定在系统中，0 是最低位，紧接着是 1，依此类推。但如果我们使用一个不同于 10 的数字为幂底会是什么样呢？我们在系统中使用的十六进制就是这样的一个数字。

上面的数学等式表明，十进制的数字 567 等于十六进制的数字 237。通常我们需要在系统中明确它们，我们使用下标 ₁₀ 表示它是十进制数字，用下标 ₁₆ 表示它是十六进制数字。由于在汇编代码中写上下标的小数字很困难，因此我们使用 0x 来表示它是一个十六进制的数字，因此 0x237 的意思就是 237 ₁₆ 。

那么，后面的 a、b、c、d、e 和 f 又是什么呢？好问题！在十六进制中为了能够写每个数字，我们就需要额外的东西。例如 9 ₁₆ = 9×16 ⁰ = 9 ₁₀ ，但是 10 ₁₆ = 1×16 ¹ + 1×16 ⁰ = 16 ₁₀ 。因此，如果我们只使用 0、1、2、3、4、5、6、7、8 和 9，我们就无法写出 10 ₁₀ 、11 ₁₀ 、12 ₁₀ 、13 ₁₀ 、14 ₁₀ 、15 ₁₀ 。因此我们引入了 6 个新的数字，这样 a ₁₆ = 10 ₁₀ 、b ₁₆ = 11 ₁₀ 、c ₁₆ = 12 ₁₀ 、d ₁₆ = 13 ₁₀ 、e ₁₆ = 14 ₁₀ 、f ₁₆ = 15 ₁₀ 。

所以，我们就有了另一种写数字的方式。但是我们为什么要这么麻烦呢？好问题！由于计算机总是工作在二进制中，事实证明，十六进制是非常有用的，因为每个十六进制数字正好是四个二进制数字的长度。这种方法还有另外一个好处，那就是许多计算机的数字都是十六进制的整数倍，而不是十进制的整数倍。比如，我在上面的汇编代码中使用的一个数字 20200000 ₁₆ 。如果我们用十进制来写，它就是一个不太好记住的数字 538968064 ₁₀ 。

我们可以用下面的简单方法将十进制转换成十六进制：

1. 我们以十进制数字 567 为例来说明。
2. 将十进制数字 567 除以 16 并计算其余数。例如 567 ÷ 16 = 35 余数为 7。
3. 在十六进制中余数就是答案中的最后一位数字，在我们的例子中它是 7。
4. 重复第 2 步和第 3 步，直到除法结果的整数部分为 0。例如 35 ÷ 16 = 2 余数为 3，因此 3 就是答案中的下一位。2 ÷ 16 = 0 余数为 2，因此 2 就是答案的接下来一位。
5. 一旦除法结果的整数部分为 0 就结束了。答案就是反序的余数，因此 567 ₁₀ = 237 ₁₆。

转换十六进制数字为十进制，也很容易，将数字展开即可，因此 237 ₁₆ = 2×16 ² + 3×16 ¹ +7 ×16 ⁰ = 2×256 + 3×16 + 7×1 = 512 + 48 + 7 = 567。

因此，我们所写的第一个汇编命令是将数字 20200000 ₁₆ 加载到寄存器 r0 中。那个命令看起来似乎没有什么用，但事实并非如此。在计算机中，有大量的内存块和设备。为了能够访问它们，我们给每个内存块和设备指定了一个地址。就像邮政地址或网站地址一样，它用于标识我们想去访问的内存块或设备的位置。计算机中的地址就是一串数字，因此上面的数字 20200000 ₁₆ 就是 GPIO 控制器的地址。这个地址是由制造商的设计所决定的，他们也可以使用其它地址（只要不与其它的冲突即可）。我之所以知道这个地址是 GPIO 控制器的地址是因为我看了它的手册， ³ 地址的使用没有专门的规范（除了它们都是以十六进制表示的大数以外）。

4、启用输出

阅读了手册可以得知，我们需要给 GPIO 控制器发送两个消息。我们必须用它的语言告诉它，如果我们这样做了，它将非常乐意实现我们的意图，去打开 OK 的 LED 指示灯。幸运的是，它是一个非常简单的芯片，为了让它能够理解我们要做什么，只需要给它设定几个数字即可。

mov r1,#1
lsl r1,#18
str r1,[r0,#4]

mov reg,#val 将数字 val 放到名为 reg 的寄存器中。

lsl reg,#val 将寄存器 reg 中的二进制操作数左移 val 位。

str reg,[dest,#val] 将寄存器 reg 中的数字保存到地址 dest + val 上。

这些命令的作用是在 GPIO 的第 16 号插针上启用输出。首先我们在寄存器 r1 中获取一个必需的值，接着将这个值发送到 GPIO 控制器。因此，前两个命令是尝试取值到寄存器 r1 中，我们可以像前面一样使用另一个命令 ldr 来实现，但 lsl 命令对我们后面能够设置任何给定的 GPIO 针比较有用，因此从一个公式中推导出值要比直接写入来好一些。表示 OK 的 LED 灯是直接连线到 GPIO 的第 16 号针脚上的，因此我们需要发送一个命令去启用第 16 号针脚。

寄存器 r1 中的值是启用 LED 针所需要的。第一行命令将数字 1 ₁₀ 放到 r1 中。在这个操作中 mov 命令要比 ldr 命令快很多，因为它不需要与内存交互，而 ldr 命令是将需要的值从内存中加载到寄存器中。尽管如此，mov 命令仅能用于加载某些值。 ⁴ 在 ARM 汇编代码中，基本上每个指令都使用一个三字母代码表示。它们被称为助记词，用于表示操作的用途。mov 是 “move” 的简写，而 ldr 是 “load register” 的简写。mov 是将第二个参数 #1 移动到前面的 r1 寄存器中。一般情况下，# 肯定是表示一个数字，但我们已经看到了不符合这种情况的一个反例。

第二个指令是 lsl（逻辑左移）。它的意思是将第一个参数的二进制操作数向左移第二个参数所表示的位数。在这个案例中，将 1 ₁₀ （即 1 ₂ ）向左移 18 位（将它变成 1000000000000000000 ₂=262144 ₁₀ ）。

如果你不熟悉二进制表示法，可以看下面的内容：

延伸阅读： 二进制解释

与十六进制一样，二进制是写数字的另一种方法。在二进制中只有两个数字，即 0 和 1。它在计算机中非常有用，因为我们可以用电路来实现它，即电流能够通过电路表示为 1，而电流不能通过电路表示为 0。这就是计算机能够完成真实工作和做数学运算的原理。尽管二进制只有两个数字，但它却能够表示任何一个数字，只是写起来有点长而已。

这个图片展示了 567 ₁₀ 的二进制表示是 1000110111 ₂ 。我们使用下标 2 来表示这个数字是用二进制写的。

我们在汇编代码中大量使用二进制的其中一个巧合之处是，数字可以很容易地被 2 的幂（即 1、2、4、8、16）乘或除。通常乘法和除法都是非常难的，而在某些特殊情况下却变得非常容易，所以二进制非常重要。

将一个二进制数字左移 n 位就相当于将这个数字乘以 2 ⁿ。因此，如果我们想将一个数乘以 4，我们只需要将这个数字左移 2 位。如果我们想将它乘以 256，我们只需要将它左移 8 位。如果我们想将一个数乘以 12 这样的数字，我们可以有一个替代做法，就是先将这个数乘以 8，然后再将那个数乘以 4，最后将两次相乘的结果相加即可得到最终结果（N × 12 = N × (8 + 4) = N × 8 + N × 4）。

右移一个二进制数 n 位就相当于这个数除以 2 ⁿ 。在右移操作中，除法的余数位将被丢弃。不幸的是，如果对一个不能被 2 的幂次方除尽的二进制数字做除法是非常难的，这将在 课程 9 Screen04 中讲到。

这个图展示了二进制常用的术语。一个 比特 bit 就是一个单独的二进制位。一个“ 半字节 nibble “ 是 4 个二进制位。一个 字节 byte 是 2 个半字节，也就是 8 个比特。 半字 half 是指一个字长度的一半，这里是 2 个字节。 字 word 是指处理器上寄存器的大小，因此，树莓派的字长是 4 字节。按惯例，将一个字最高有效位标识为 31，而将最低有效位标识为 0。顶部或最高位表示最高有效位，而底部或最低位表示最低有效位。一个 kilobyte（KB）就是 1000 字节，一个 megabyte 就是 1000 KB。这样表示会导致一些困惑，到底应该是 1000 还是 1024（二进制中的整数）。鉴于这种情况，新的国际标准规定，一个 KB 等于 1000 字节，而一个 Kibibyte（KiB）是 1024 字节。一个 Kb 是 1000 比特，而一个 Kib 是 1024 比特。

树莓派默认采用小端法，也就是说，从你刚才写的地址上加载一个字节时，是从一个字的低位字节开始加载的。

再强调一次，我们只有去阅读手册才能知道我们所需要的值。手册上说，GPIO 控制器中有一个 24 字节的集合，由它来决定 GPIO 针脚的设置。第一个 4 字节与前 10 个 GPIO 针脚有关，第二个 4 字节与接下来的 10 个针脚有关，依此类推。总共有 54 个 GPIO 针脚，因此，我们需要 6 个 4 字节的一个集合，总共是 24 个字节。在每个 4 字节中，每 3 个比特与一个特定的 GPIO 针脚有关。我们想去启用的是第 16 号 GPIO 针脚，因此我们需要去设置第二组 4 字节，因为第二组的 4 字节用于处理 GPIO 针脚的第 10-19 号，而我们需要第 6 组 3 比特，它在上面的代码中的编号是 18（6×3）。

最后的 str（“store register”）命令去保存第一个参数中的值，将寄存器 r1 中的值保存到后面的表达式计算出来的地址上。这个表达式可以是一个寄存器，在上面的例子中是 r0，我们知道 r0 中保存了 GPIO 控制器的地址，而另一个值是加到它上面的，在这个例子中是 #4。它的意思是将 GPIO 控制器地址加上 4 得到一个新的地址，并将寄存器 r1 中的值写到那个地址上。那个地址就是我们前面提到的第二组 4 字节的位置，因此，我们发送我们的第一个消息到 GPIO 控制器上，告诉它准备启用 GPIO 第 16 号针脚的输出。

5、生命的信号

现在，LED 已经做好了打开准备，我们还需要实际去打开它。意味着需要给 GPIO 控制器发送一个消息去关闭 16 号针脚。是的，你没有看错，就是要发送一个关闭的消息。芯片制造商认为，在 GPIO 针脚关闭时打开 LED 更有意义。 ⁵ 硬件工程师经常做这种反常理的决策，似乎是为了让操作系统开发者保持警觉。可以认为是给自己的一个警告。

mov r1,#1
lsl r1,#16
str r1,[r0,#40]

希望你能够认识上面全部的命令，先不要管它的值。第一个命令和前面一样，是将值 1 推入到寄存器 r1 中。第二个命令是将二进制的 1 左移 16 位。由于我们是希望关闭 GPIO 的 16 号针脚，我们需要在下一个消息中将第 16 比特设置为 1（想设置其它针脚只需要改变相应的比特位即可）。最后，我们写这个值到 GPIO 控制器地址加上 40 ₁₀ 的地址上，这将使那个针脚关闭（加上 28 将打开针脚）。

6、永远幸福快乐

似乎我们现在就可以结束了，但不幸的是，处理器并不知道我们做了什么。事实上，处理器只要通电，它就永不停止地运转。因此，我们需要给它一个任务，让它一直运转下去，否则，树莓派将进入休眠（本示例中不会，LED 灯会一直亮着）。

loop$:
b loop$

name: 下一行的名字。

b label 下一行将去标签 label 处运行。

第一行不是一个命令，而是一个标签。它给下一行命名为 loop$，这意味着我们能够通过名字来指向到该行。这就称为一个标签。当代码被转换成二进制后，标签将被丢弃，但这对我们通过名字而不是数字（地址）找到行比较有用。按惯例，我们使用一个 ​$ 表示这个标签只对这个代码块中的代码起作用，让其它人知道，它不对整个程序起作用。b（“branch”）命令将去运行指定的标签中的命令，而不是去运行它后面的下一个命令。因此，下一行将再次去运行这个 b 命令，这将导致永远循环下去。因此处理器将进入一个无限循环中，直到它安全关闭为止。

代码块结尾的一个空行是有意这样写的。GNU 工具链要求所有的汇编代码文件都是以空行结束的，因此，这就可以你确实是要结束了，并且文件没有被截断。如果你不这样处理，在汇编器运行时，你将收到烦人的警告。

7、树莓派上场

由于我们已经写完了代码，现在，我们可以将它上传到树莓派中了。在你的计算机上打开一个终端，改变当前工作目录为 source 文件夹的父级目录。输入 make 然后回车。如果报错，请参考排错章节。如果没有报错，你将生成三个文件。 kernel.img 是你的编译后的操作系统镜像。kernel.list 是你写的汇编代码的一个清单，它实际上是生成的。这在将来检查程序是否正确时非常有用。kernel.map 文件包含所有标签结束位置的一个映射，这对于跟踪值非常有用。

为安装你的操作系统，需要先有一个已经安装了树莓派操作系统的 SD 卡。如果你浏览 SD 卡中的文件，你应该能看到一个名为 kernel.img 的文件。将这个文件重命名为其它名字，比如 kernel_linux.img。然后，复制你编译的 kernel.img 文件到 SD 卡中原来的位置，这将用你的操作系统镜像文件替换现在的树莓派操作系统镜像。想切换回来时，只需要简单地删除你自己的 kernel.img 文件，然后将前面重命名的文件改回 kernel.img 即可。我发现，保留一个原始的树莓派操作系统的备份是非常有用的，万一你要用到它呢。

将这个 SD 卡插入到树莓派，并打开它的电源。这个 OK 的 LED 灯将亮起来。如果不是这样，请查看故障排除页面。如果一切如愿，恭喜你，你已经写出了你的第一个操作系统。课程 2 OK02 将指导你让 LED 灯闪烁和关闭闪烁。

1. 是的，我说错了，它告诉的是链接器，它是另一个程序，用于将汇编器转换过的几个代码文件链接到一起。直接说是汇编器也没有大问题。 ↩
2. 其实它们对你很重要。由于 GNU 工具链主要用于开发操作系统，它要求入口点必须是名为 _start 的地方。由于我们是开发一个操作系统，无论什么时候，它总是从 _start 开时的，而我们可以使用 .section .init 命令去设置它。因此，如果我们没有告诉它入口点在哪里，就会使工具链困惑而产生警告消息。所以，我们先定义一个名为 _start 的符号，它是所有人可见的（全局的），紧接着在下一行生成符号 _start 的地址。我们很快就讲到这个地址了。 ↩
3. 本教程的设计减少了你阅读树莓派开发手册的难度，但是，如果你必须要阅读它，你可以在这里 SoC-Peripherals.pdf 找到它。由于添加了混淆，手册中 GPIO 使用了不同的地址系统。我们的操作系统中的地址 0x20200000 对应到手册中是 0x7E200000。 ↩
4. mov 能够加载的值只有前 8 位是 1 的二进制表示的值。换句话说就是一个 0 后面紧跟着 8 个 1 或 0。 ↩
5. 一个很友好的硬件工程师是这样向我解释这个问题的： ↩

原因是现在的芯片都是用一种称为 CMOS 的技术来制成的，它是互补金属氧化物半导体的简称。互补的意思是每个信号都连接到两个晶体管上，一个是使用 N 型半导体的材料制成，它用于将电压拉低，而另一个使用 P 型半导体材料制成，它用于将电压升高。在任何时刻，仅有一个半导体是打开的，否则将会短路。P 型材料的导电性能不如 N 型材料。这意味着三倍大的 P 型半导体材料才能提供与 N 型半导体材料相同的电流。这就是为什么 LED 总是通过降低为低电压来打开它，因为 N 型半导体拉低电压比 P 型半导体拉高电压的性能更强。

还有一个原因。早在上世纪七十年代，芯片完全是由 N 型材料制成的（NMOS），P 型材料部分使用了一个电阻来代替。这意味着当信号为低电压时，即便它什么事都没有做，芯片仍然在消耗能量（并发热）。你的电话装在口袋里什么事都不做，它仍然会发热并消耗你的电池电量，这不是好的设计。因此，信号设计成 “活动时低”，而不活动时为高电压，这样就不会消耗能源了。虽然我们现在已经不使用 NMOS 了，但由于 N 型材料的低电压信号比 P 型材料的高电压信号要快，所以仍然使用了这种设计。通常在一个 “活动时低” 信号名字上方会有一个条型标记，或者写作 SIGNAL_n 或 /SIGNAL。但是即便这样，仍然很让人困惑，那怕是硬件工程师，也不可避免这种困惑！

via: https://www.cl.cam.ac.uk/projects/raspberrypi/tutorials/os/ok01.html

作者：Robert Mullins 选题：lujun9972 译者：qhwdw 校对：wxy

本文由 LCTT 原创编译，Linux中国 荣誉推出

这个课程简介不包含实践内容，但它解释了一个操作系统的基本概念、汇编代码、和其它很重要的一些基本原理。如果你想直接进入实践环节，跳过本课程并不会有什么问题。

1、操作系统

操作系统就是一个非常复杂的程序。它的任务就是组织安排计算机上的其它程序，包括共享计算机的时间、内存、硬件和其它资源。你可能听说过的一些比较大的桌面操作系统家族有 GNU/Linux、Mac OS X 和 Microsoft Windows。其它的设备比如电话，也需要操作系统，它可能使用的操作系统是 Android、iOS 和 Windows Phone。 ¹

由于操作系统是用来与计算机系统上的硬件进行交互的，所以它必须了解系统上硬件专有的信息。为了能让操作系统适用于各种类型的计算机，发明了 驱动程序 的概念。驱动程序是为了能够让操作系统与特定的硬件进行交互而添加（并可删除）到操作系统上的一小部分代码。在本课程中，我们并不涉及如何创建可删除的驱动程序，而是专注于特定的一个硬件：树莓派。

操作系统有各种不同的设计方式，在本课程中，我们只触及操作系统设计的皮毛。本课程中，我们主要专注于操作系统与各种硬件的交互部分，因为这经常是比较棘手的部分，并且也是在网络上文档和帮助最少的部分。

2、汇编代码

处理器每秒可以执行上百万的指令，但是这些指令必须要简单。

本课程几乎要完全靠汇编代码来写。汇编代码非常接近计算机的底层。计算机其实是靠一个叫处理器的设备来工作的，处理器能够执行像加法这样的简单任务，还有一组叫做 RAM 的芯片，它能够用来保存数字。当计算机通电后，处理器执行程序员给定的一系列指令，这将导致内存中的数字发生变化，以及与连接的硬件进行交互。汇编代码只是将这些机器命令转换为人类可读的文本。

常规的编程就是，程序员使用编程语言，比如 C++、Java、C#、Basic 等等来写代码，然后一个叫编译器的程序将程序员写的代码转换成汇编代码，然后进一步转换为二进制代码。 ² 二进制代码才是计算机真正能够理解的东西，但它是人类无法读取的东西。汇编代码比二进制代码好一点，至少它的命令是人类可读的，但它仍然让人很沮丧。请记住，你用汇编代码写的每个命令都是处理器可以直接认识的，因此这些命令设计的很简单，因为物理电路必须能够处理每个命令。

和普通编程一样，也有很多不同的汇编代码编程语言，但与普通编程不一样的是，每个汇编编程语言是面对不同的处理器的，每种处理器设计为去理解不同的语言。因此，用一个针对某种机器设计的汇编语言所写的汇编代码，是不能在其它种类的机器上运行的。很多情况下，这都是一个大灾难，因此每个程序都必须在使用它的不同种类的机器上重写一遍，但对于操作系统，这不是个问题，因为在不同的硬件上它必须得重写。尽管如此，大多数操作系统都是用 C++ 或 C 来写的，这样它们就可以很容易地在不同种类的硬件上使用，只需要重写那些必须用汇编代码来实现的部分即可。

现在，你已经准备好进入第一节课了，它是 课程 1 OK01。

1. 要查看更完整的操作系统列表，请参照：操作系统列表 - Wikipedia ↩
2. 当然，我简化了普通编程的这种解释，实际上它在很大程度上取决于语言和机器。感兴趣的话，参见 编译器 - Wikipedia ↩

via: https://www.cl.cam.ac.uk/projects/raspberrypi/tutorials/os/introduction.html

作者：Robert Mullins 选题：lujun9972 译者：qhwdw 校对：wxy

本文由 LCTT 原创编译，Linux中国 荣誉推出